# seed sorter using the in-sorter memory instructions

alias sorter r15
alias sortername r14
alias seedhash r13
alias chutepolarity r12 # 1 means divert, 2 means straight

define HASHSORTER HASH("StructureLogicSorter")

start:
yield

move sortername HASH("Sorter Corn vending")
move seedhash HASH("SeedBag_Corn")
#move seedhash HASH("ItemKitChute")
move chutepolarity 1
jal doone

move sortername HASH("Sorter Wheat vending")
move seedhash HASH("SeedBag_Wheet") # sic
move chutepolarity 1
jal doone

move sortername HASH("Sorter Rice vending")
move seedhash HASH("SeedBag_Rice")
move chutepolarity 1
jal doone

move sortername HASH("Sorter Pumpkin vending")
move seedhash HASH("SeedBag_Pumpkin")
move chutepolarity 1
jal doone

move sortername HASH("Sorter Tomato vending")
move seedhash HASH("SeedBag_Tomato")
move chutepolarity 1
jal doone

move sortername HASH("Sorter Soybean vending")
move seedhash HASH("SeedBag_Soybean")
move chutepolarity 1
jal doone

j start


doone:

lbn sorter HASHSORTER sortername ReferenceId Minimum
s db Setting sorter
beqz sorter ra
sub r1 3 chutepolarity
lbns  r0 HASHSORTER sortername r1 Occupied Maximum

sd sorter Mode chutepolarity
clrd sorter

bnez r0 clogged1

s db Setting 9
sll r0 seedhash 8
or r0 r0 SorterInstruction.FilterPrefabHashEquals
putd sorter 0 r0

j ra

clogged1:
s db Setting 8
putd sorter 0 SorterInstruction.FilterPrefabHashEquals  # itemhash 0 matches

j ra