# 2022-Aug

alias indicator d0

#limiting pressures
define inletTrigger 10 #inlet above this turns on filter unless...
define outletLimit 8000 #outlet or storage above this turns off filter
define Green 2
define Orange 3
define Red 4
define Yellow 5

s indicator Color 11
s db Mode 0
start:
yield

ls r1 db 0 Quantity
sle r0 r1 0 #filter failed
ls r2 db 1 Quantity
sle r3 r2 0 # 2nd filter failed
min r0 r3 r0 # are both filters failed?
blez r0 atleastonefilter
bdns indicator noled1
s indicator On 1
s indicator Color Red
noled1:
s db Mode 0 # turn off the filter
j start

atleastonefilter:
bdns indicator afterled

min r0 r1 r2 #is either filter failed?
bgtz r0 nodeadfilters
s indicator On 1
s indicator Color Yellow
j afterled

nodeadfilters:

add r0 r1 r2
bgt r0 9 goodfilters
s indicator On 1
s indicator Color Orange

j afterled

goodfilters:
s indicator On 0
s indicator Color Green

afterled:

l r0 db PressureInput
sgt r1 r0 inletTrigger

l r0 db TemperatureInput
sgt r0 r0 320
or r1 r0 r1

l r0 db PressureOutput
slt r2 r0 outletLimit
min r1 r1 r2

l r0 db PressureOutput2
slt r2 r0 outletLimit
min r1 r1 r2

s db Mode r1

bgtz r1 start

sleep 10

j start